\class {vpane}
\name {voter2}
\children {voter2.label voter2.rating}
\script {
	switch (arg[0]) {
	case "make":
		votingOn = arg[2];
		info = send("ratedUrlDB", "fetch", votingOn);
		if (info) send("voter2.rating", "setRate", int(info[0]));
		return;
	break;
	case "submit":
		print(">>>>>>>> SUBMIT: doc = {", votingOn, "}  rating = ",
			arg[1], "\n");

		HTTPGet(concat("http://marble.ebay.gnn.com/cgi-bin/votepg?", 
				votingOn, "=", arg[1]));
		send("ratedUrlDB", "put", votingOn, arg[1], "description...");
		send("ratedUrlDB", "flush");
		return;
	break;
	}
	usual();
}
\maxWidth {100}
\border {6}
\gapH {2}
\gapV {2}
\
\class {txtLabel}
\name {voter2.label}
\parent {voter2}
\label {Page Voter}
\paneConfig {westToEast}
\script {
	switch (arg[0]) {
	case "hint":
		return "Vote on the doucment!";
	break;
	case "enter":
	case "leave":
		send("www.mesg.tf", "suggest", self(), arg[0]);
	break;
	}
	usual();
}
\gapH {2}
\
\class {menu}
\parent {voter2}
\name {voter2.rating}
\menuConfig {
. {Excellent} 	{send(self(), "rating", 4, "Excellent");}
. {Good} 	{send(self(), "rating", 3, "Good");}
. {Average} 	{send(self(), "rating", 2, "Average");}
. {Poor} 	{send(self(), "rating", 1, "Poor");}
}
\label {unrated}
\script {
	switch (arg[0]) {
	case "rating":
		set("label", arg[2]);
		render();
		send(parent(), "submit", arg[1]);
		return;
	break;
	case "setRate":
		switch (arg[1]) {
		case 1: set("label", "Poor"); 		break;
		case 2: set("label", "Average"); 	break;
		case 3: set("label", "Good"); 		break;
		case 4: set("label", "Excellent"); 	break;
		}
		render();
		return;
	break;
	case "hint":
		return "Choose a rating...";
	break;
	}
	usual();	
}
\border {3}
\gapH {2}
\